Hello，大家好，今天跟大家分享一个“跨界函数”的天花板，他就是rept函数，它的本意是用于重复字符串，但是如果配合特殊的字体使用，我们工作中常见的甘特图，旋风图，瀑布图等等都可以轻松搞定，今天我们就来get下它的使用方法吧

想要从零学习Excel，这里↑↑↑↑↑↑

一、Rept的作用

REPT：将指定的文本重复相应的次数

语法：=REPT(text, number_times)

第一参数：需要重复的文本

第二参数:文本重复的次数。必须是一个正数，如果设置为负数，函数会显示#VALUE!这个错误值，如果设置为了一个 小数，函数会向下取整，比如设置为5.8，就会默认将第二参数设置为5，将第一参数重复5次。

下图就是它的实际效果，当我们将函数的第一参数设置为【我】字，将第二参数设置为6的时候，它输出的结果就是6个我字，随后我们来看下他能解决哪些问题

二、Rept常规用法

1.设置手机号码保护

公式：=LEFT(A3,3)&REPT("*",4)&RIGHT(A3,4)

在这里我们使用left函数提取手机号码的前三位，在使用rigth函数提取手机号码的后四位，在使用链接符号将*号重复4次，最后把它们连接在一起就好了

2.星级判定

公式：=REPT("⭐",B3/15)

这个幸幸符号是用输入法打出来的，随后将第二参数都除以15，缩小相同的倍数。如果你使用的是win10以上的系统，可以按下Windows键+句号，来调出系统自带的表情符号，制作更多的显示效果

三、图表制作

使用REPT函数制作图表，我们需要配合Playbill这个字体来构建，几乎所有以条形图构建的图表REPT函数都可以轻松搞定，下面我们就来着手制作下吧

1.条形图

公式：=REPT("|",A3)&" "&A3

在这里我们将REPT函数的第一参数设置为了竖线，让竖线重复多次，在Playbill字体下竖线会被显示为一个条形，这个就是图表的制作原理，在REPT函数后面我们分别链接了空格与销量，这个是为了让销量与条形图留有余量更加好看

2.柱形图

公式：=REPT("|",B3)&" "&B3

方法与条形图是一模一样的，在制作柱形图的时候我们需要选择图形区域，在文字旋转中选择【向上旋转文字】随后将对齐方式设置为【底端对齐】与【居中对齐】

3.瀑布图与堆积图

公式：=REPT("|",B3*2)&" "&B3

原理与制作【条形图】是一模一样的，我们将数值【降序排序】就是一个【瀑布图】，将数值【升序排序】就是一个【阶梯图】，在这里我们将销量扩大了2倍，让它看起来更加的和谐，还有一个需要注意的是需要将文字的2个对齐方式都设置为【居中】

4.盈亏图

亏损公式：=IF(B3<0,B3&" ","")&IF(B3<0,REPT("|",ABS(B3)*5),"")

对齐方式为：居中与右对齐

盈利公式：=IF(B3>0,REPT("|",ABS(B3)*5),"")&IF(B3>0," "&B3,"")

对齐方式为：居中与左对齐

IF函数的作用是根据正负数据返回对应的列，ABS函数它的作用是返回数据的绝对值，利用它可以将负数变为正数放在REPT函数的第二参数中，最后我们将亏损字体设置为红色，盈利字体设置为绿色即可

5.甘特图

公式：=REPT(" ",B3-MIN($B$3:$B$6))&REPT("|",D3*8)

函数可以拆分为2个部分来讲解

第一部分：REPT(" ",B2-MIN($B$2:$B$5))第一参数设置的是空格，第二参数用开始时间减去最小开始时间，让最小时间的甘特图从最左边开始，并且可以利用这个特性来填充空格

第二部分： REPT("|",D2*8)它的作用是用来重复填充竖线，因为天数太小所以我们将它放大8倍，大家可以根据自己的图表数据进行放大

6.旋风图

赞成公式：=B4*100&"%"&" "&REPT("|",B4*200)

对齐方式为：居中以及右对齐

反对公式：=REPT("|",C4*200)&" "&C4*100&"%"

对齐方式为：居中以及左对齐

这个主要是构建后面显示的百分号，就是B4*100&"%"这个公式，我们先把数据扩大100倍，然后为其连接一个百分号，看起来就是百分比的样子了~

以上就是今天分享的全部内容，在使用rept与Playbill来构建图形的时候，我们需要注意的是柱子的颜色是由字体颜色控制的，并不是由填充色控制的

我是Excel从零到一，关注我，持续分享更多Excel技巧